
**Moving average 30 days**

The moving average is typically used to display trends in line charts. Figure 18 includes the moving average of Sales Amount over 30 days (Sales AVG 30D), three months (Sales AVG 3M), and a year (Sales AVG 1Y).



The Sales AVG 30D measure computes the moving average over 30 days by iterating a list of the last 30 dates obtained by [**DATESINPERIOD**](https://dax.guide/datesinperiod/?aff=dax-patterns):

Sales AVG 30D :=

VAR Period30D =

    CALCULATETABLE (

        DATESINPERIOD (

            'Date'[Date],

            MAX ( 'Date'[Date] ),

            -30,

            DAY

        ),

        'Date'[DateWithSales] = TRUE

    )

VAR FirstDayWithData =

    CALCULATE (

        MIN ( Sales[Order Date] ),

        REMOVEFILTERS ()

    )

VAR FirstDayInPeriod =

    MINX ( Period30D, 'Date'[Date] )

VAR Result =

    IF (

        FirstDayWithData <= FirstDayInPeriod,

        AVERAGEX (

            Period30D,

            [Sales Amount]

        )

    )

RETURN

    Result

This pattern is very flexible. But for a regular additive calculation, Result can be implemented using a different and faster formula:

VAR Result =

    IF (

        FirstDayWithData <= FirstDayInPeriod,

        CALCULATE (

            DIVIDE (

                [Sales Amount],

                DISTINCTCOUNT ( Sales[Order Date] )

            ),

            Period30D

        )

    )

## Moving average 3 months

The Sales AVG 3M measure computes the moving average over three months by iterating a list of the dates in the last three months obtained by [**DATESINPERIOD**](https://dax.guide/datesinperiod/?aff=dax-patterns):

Sales AVG 3M :=

VAR Period3M =

    CALCULATETABLE (

        DATESINPERIOD (

            'Date'[Date],

            MAX ( 'Date'[Date] ),

            -3,

            MONTH

        ),

        'Date'[DateWithSales] = TRUE

    )

VAR FirstDayWithData =

    CALCULATE (

        MIN ( Sales[Order Date] ),

        REMOVEFILTERS ()

    )

VAR FirstDayInPeriod =

    MINX ( Period3M, 'Date'[Date] )

VAR Result =

    IF (

        FirstDayWithData <= FirstDayInPeriod,

        AVERAGEX (

            Period3M,

            [Sales Amount]

        )

    )

RETURN

    Result

For simple additive measures, the pattern based on [**DIVIDE**](https://dax.guide/divide/?aff=dax-patterns) which is shown for the moving average over 30 days can also be used for the average over three months.

## Moving average 1 year

The Sales AVG 1Y measure computes the moving average over one year by iterating a list of the dates in the last year obtained by [**DATESINPERIOD**](https://dax.guide/datesinperiod/?aff=dax-patterns):

Sales AVG 1Y :=

VAR Period1Y =

    CALCULATETABLE (

        DATESINPERIOD (

            'Date'[Date],

            MAX ( 'Date'[Date] ),

            -1,

            YEAR

        ),

        'Date'[DateWithSales] = TRUE

    )

VAR FirstDayWithData =

    CALCULATE (

        MIN ( Sales[Order Date] ),

        REMOVEFILTERS ()

    )

VAR FirstDayInPeriod =

    MINX ( Period1Y, 'Date'[Date] )

VAR Result =

    IF (

        FirstDayWithData <= FirstDayInPeriod,

        AVERAGEX (

            Period1Y,

            [Sales Amount]

        )

    )

RETURN

    Result

For simple additive measures, the same pattern based on [**DIVIDE**](https://dax.guide/divide/?aff=dax-patterns), shown for the moving average over 30 days can also be used for the average over one year.